ユーザーフォームにテキストボックス(TextBox)を追加する方法と詳細設定の方法をご説明します。
テキストボックスは文字列や数値を入力、表示する場合に使用します。
また、入力、表示されている値の取得や変更が可能です。
そのため使用頻度の高いコントロールかと思います。
追加するにはツールボックスから追加する方法と、VBAから追加する方法がありますので、順にご説明します。
また、サンプルコードではループを使用して複数のコントロールの追加や、設置済みのテキストボックスを取得して詳細設定するサンプルコードも記載したいと思います。
その他のコントロールの操作については下記記事をご覧ください。
- ユーザーフォームにコントロールを追加する方法
- ラベルを追加と詳細設定する方法
- コンボボックスの追加とリスト作成、詳細設定の方法
- チェックボックスを追加と詳細設定する方法
- テキストボックスに入力されている値を取得する方法
- リストボックス追加とリスト作成、詳細設定の方法
- オプションボタンの追加と詳細設定する方法
- コマンドボタンの追加と詳細設定する方法
- フレームの追加と詳細設定する方法
1.ツールボックスでテキストボックスを追加する
まずは、ツールボックスでテキストボックスを追加する方法です。
ユーザーフォームの作成がまだの方は、VBE→挿入タブ→ユーザーフォームを選択してUserFormを作成してください。
ツールボックスが表示されていない方は、メニューの実行ボタンや停止ボタンの並びにあるツールボックスボタンをクリックしてください。
もしくは表示タブのツールボックスを選択する事で表示出来ます。
ツールボックスの「ab」というアイコンがテキストボックスですので、選択します。
選択したら、ユーザーフォーム上の設置したい位置でユーザーフォームをクリックします。
すると下記図のように、テキストボックスが追加されます。
2.プロパティウィンドウで詳細設定する
テキストボックスを大まかな位置に設置したら、次はプロパティウィンドウで詳細設定をします。
詳細設定と言ってもプロパティの種類が多すぎますので、一覧で簡単に説明します。
プロパティ一覧
定数の説明があるプロパティは赤字になっています。
| プロパティ名 | 説明 |
| オブジェクト名 | コントロールの名前を指定します。 |
| AutoSize | 文字列に合わせて文字列の表示領域を自動で調整するか指定します。 |
| AutoTab | MaxLengthに設定された入力できる最大文字数が入力されたとき、 フォーカスを自動的に次のコントロールに移動するか指定します。 |
| AutoWordSelect | 入力されている文字列をダブルクリックした場合に、 選択範囲を単語単位かすべての文字列にするか指定します。 |
| BackColor | 背景色をシステムまたは、カラーパレットで指定します。 |
| BackStyle | 背景のスタイルを指定します。 |
| BorderColor | 枠線の色をシステムまたは、カラーパレットで指定します。 |
| BorderStyle | 枠線のスタイルを指定します。 |
| ControlSource | リンクさせるセルのアドレスを指定します。 |
| ControlTipText | マウスポインタｰを上に置いたとき、表示する文字列を指定します。 |
| DragBehavior | ドラッグ&ドロップを許可するか指定します。 |
| Enabled | イベントに対応するか指定します。 |
| EnterFieldBehavior | フォーカスされた場合に文字列を選択するか指定します。 |
| EnterKeyBehavior | テキストボックスでEnterを押した場合の動作を指定します。 |
| Font | 文字列のフォントの種類やサイズを指定します。 |
| ForeColor | 文字列の色を指定します。 |
| Height | 高さを指定します。 |
| HideSelection | フォーカスが外れた際に選択されているテキストが強調されたままか指定します。 |
| IMEMode | 日本語入力システムの実行モードを指定します。 |
| IntegralHeight | リストですべて、または一部のテキスト行のどちらを表示するか指定します。 |
| Left | 位置をフォームの左端を0として、ポイント単位で指定します。 |
| Locked | テキストボックスが編集できるか指定します。 |
| MaxLength | 入力できる最大文字数を指定します。 |
| MouseIcon | マウスポインターがテキストボックス上にあるときアイコンファイルを指定します。 |
| MousePointer | マウスポインターがテキストボックスに移動したとき、 表示されるポインターの種類を指定します。 |
| MultiLine | 文字列を改行して複数行入力できるか指定します。 |
| PasswordChar | パスワード入力で使用する場合は隠し文字を指定します。 |
| ScrollBars | スクロールバーの表示設定をします。 |
| SelectionMargin | 文字列をワンクリックで選択可能にする、 左端余白の有効・無効を指定します。 |
| SpecialEffect | テキストボックスの表面の立体表示を指定します。 |
| TabIndex | テキストボックスにフォーカスをあてる順番を指定します。 |
| TabKeyBehavior | テキストボックス上でTabキーを押した場合の動作を指定します。 |
| TabStop | TabIndexの有効/無効を指定します。 |
| Text | 表示する文字列を指定します。 |
| TextAlign | テキストボックスの文字列の位置を指定します。 |
| Top | 位置をフォームの上端を0としてポイント単位で指定します。 |
| Value | 文字列を指定します。 |
| Visible | 表示/非表示を切り替えます。 |
| Width | 幅をポイント単位で指定します。 |
| WordWrap | テキストボックス内の文字列が幅を超えたときの折り返しを指定します。 |
BackStyleの定数一覧
「fmBackStyleOpaque」が既定値となります。
| 定数名 | 値 | 説明 |
| fmBackStyleTransparent | 0 | 背景を透明にします。 |
| fmBackStyleOpaque | 1 | BackColor設定した色に背景を塗りつぶします。 |
BorderStyleの定数一覧
「fmBorderStyleNone」が既定値となります。
| 定数名 | 値 | 説明 |
| fmBorderStyleNone | 0 | 枠線を表示しません。 |
| fmBorderStyleSingle | 1 | 枠線を表示します。 |
DragBehaviorの定数一覧
「fmDragBehaviorDisabled」が既定値となります。
| 定数名 | 値 | 説明 |
| fmDragBehaviorDisabled | 0 | ドラッグ&ドロップを許可しません。 |
| fmDragBehaviorEnabled | 1 | ドラッグ&ドロップを許可します。 |
EnterFieldBehaviorの定数一覧
「fmEnterFieldBehaviorSelectAll」が既定値となります。
| 定数名 | 値 | 説明 |
| fmEnterFieldBehaviorSelectAll | 0 | 文字列をすべて選択します。（既定値） |
| FmEnterFieldBehaviorRecallSelection | 1 | 文字列を選択しません。 |
IMEModeの定数一覧
「fmIMEModeNoControl」が既定値となります。
| 定数名 | 値 | 説明 |
| fmIMEModeNoControl | 0 | IMEのモードを変更しません。 |
| fmIMEModeOn | 1 | IMEをオンにします。 |
| fmIMEModeOff | 2 | IMEをオフにして英語モードにします。 |
| fmIMEModeDisable | 3 | IMEをオフにし、キー操作によってIMEをオンにできません。 |
| fmIMEModeHiragana | 4 | 全角ひらがなモードでIMEをオンにします。 |
| fmIMEModeKatakana | 5 | 全角カタカナモードでIMEをオンにします。 |
| fmIMEModeKatakanaHalf | 6 | 半角カタカナモードでIMEをオンにします。 |
| fmIMEModeAlphaFull | 7 | 全角英数モードでIMEをオンにします。 |
| fmIMEModeAlpha | 8 | 半角英数モードでIMEをオンにします。 |
MousePointerの定数一覧
「fmMousePointerDefault」が既定値となります。
| 定数名 | 値 | 内容 |
| fmMousePointerDefault | 0 | 標準ポインター |
| fmMousePointerArrow | 1 | 矢印 |
| fmMousePointerCross | 2 | 十字ポインター |
| fmMousePointerIBeam | 3 | Iビーム |
| fmMousePointerSizeNESW | 6 | 右上と左下を指し示す両端矢印 |
| fmMousePointerSizeNS | 7 | 上と下を指し示す両端矢印 |
| fmMousePointerSizeNWSE | 8 | 左上と右下を指し示す両端矢印 |
| fmMousePointerSizeWE | 9 | 左と右を指し示す両端矢印 |
| fmMousePointerUpArrow | 10 | 上向き矢印 |
| fmMousePointerHourglass | 11 | 砂時計 |
| fmMousePointerNoDrop | 12 | ドラッグされているオブジェクトに重なった不可シンボル無効なターゲット。 |
| fmMousePointerAppStarting | 13 | 矢印と砂時計 |
| fmMousePointerHelp | 14 | 矢印と疑問符 |
| fmMousePointerSizeAll | 15 | サイズ変更カーソル (上下左右を指し示す矢印) |
| fmMousePointerCustom | 99 | MouseIcon プロパティで指定されたアイコンを使用します。 |
ScrollBarsの定数一覧
「fmScrollBarsNone」が既定値となります。
| 定数名 | 値 | 説明 |
| fmScrollBarsNone | 0 | スクロールバーを表示しません。 |
| fmScrollBarsHorizontal | 1 | 水平スクロールバーを表示します。 |
| fmScrollBarsVertical | 2 | 垂直スクロールバーを表示します。 |
| fmScrollBarsBoth | 3 | 水平・垂直スクロールバーの両方を表示します。 |
TextAlignの定数一覧
「fmTextAlignLeft」が既定値となります。
| 定数名 | 値 | 位置 |
| fmTextAlignLeft | 1 | 左揃え |
| fmTextAlignCenter | 2 | 中央揃え |
| fmTextAlignRight | 3 | 右揃え |
3.VBAでテキストボックスを追加する方法
VBAでコントロールの追加は次のように記述します。
Set Object = UserForm1.Controls.Add("Forms.TextBox.1","コントロールの名前","オブジェクトの表示")コントロールオブジェクトに「Addメソッド」で追加して操作します。
テキストボックスのコントロールIDは「Forms.TextBox.1」です。
コントロールの種類とコントロールの名前、オブジェクトの表示をTrue、Falseで指定します。
「オブジェクトの表示」は省略可能で、省略した場合は既定値がTrueになります。
4.サンプルコード
テキストボックスを追加するサンプルコード
何も指定しないと左上にデフォルト設定の状態で追加されます。
また、テキストボックスを追加する際にオブジェクト名に、テキストコントロールと判定できるような名前に指定する事をおすすめします。
追加後にVBAでコントロールを特定する際に簡単になります。
Sub Sample1()
Dim MyCtrl As Object
With UserForm1
Set MyCtrl = .Controls.Add("Forms.TextBox.1", "MyText", True)
.Show vbModeless
End With
End Sub
テキストボックスの詳細設定をするサンプルコード
Sub Sample2()
Dim MyCtrl As Object
With UserForm1
Set MyCtrl = .Controls.Add("Forms.TextBox.1", "MyText", True)
With MyCtrl
.Top = 24 'Top位置
.Left = 18 'Left位置
.Height = 20 '高さ
.Width = 100 '幅
.BorderStyle = fmBorderStyleSingle '枠線
.ForeColor = RGB(0, 0, 0) '文字色
.Font.Name = "メイリオ" 'テキストのスタイル
.TextAlign = 2 'テキストの位置
.FontSize = 10 'テキストのサイズ
.IMEMode = fmIMEModeHiragana 'IMEをひらがなに指定する
.TabIndex = 1
End With
.Show vbModeless
End With
End Sub
ループで複数のテキストボックスを追加するサンプルコード
Sub Sample3()
Dim MyCtrl As Object
Dim i As Long
With UserForm1
For i = 1 To 5
'テキストボックスの名前に番号を付ける
Set MyCtrl = .Controls.Add("Forms.TextBox.1", "MyText" & i, True)
With MyCtrl
.Top = 24 * i 'Top位置(表示位置を移動する)
.Left = 18 'Left位置
.Height = 20 '高さ
.Width = 100 '幅
.BorderStyle = fmBorderStyleSingle '枠線
.ForeColor = RGB(0, 0, 0) '文字色
.Font.Name = "メイリオ" 'テキストのスタイル
.TextAlign = 2 'テキストの位置
.FontSize = 10 'テキストのサイズ
.IMEMode = fmIMEModeHiragana 'IMEをひらがなに指定する
.TabIndex = i 'タブキーの移動の順番を指定する
End With
Next i
.Show vbModeless
End With
End Sub
設置済みテキストボックスを取得して詳細設定するサンプルコード
今回はSample3のコードを使用して追加後に、取得して詳細設定を行います。
追加には「For Next」を使用していますが、取得には「For Each In Next」のループでコントロールを取得しています。
もちろん「For Next」でも取得可能です。
その場合はテキストボックスを取得するには「Controls(“コントロール名”)」で指定します。
Sub Sample4()
Dim MyCtrl As Object
Dim i As Long
Dim GetCtrl As Object
With UserForm1
'テキストボックスを5個追加
For i = 1 To 5
'テキストボックスの名前に番号を付ける
Set MyCtrl = .Controls.Add("Forms.TextBox.1", "MyText" & i, True)
Next i
.Show vbModeless
'テキストボックスを取得して詳細設定する
i = 1
For Each GetCtrl In .Controls
With GetCtrl
If InStr(.Name, "MyText") <> 0 Then
.Top = 24 * i 'Top位置(表示位置を移動する)
.Left = 18 'Left位置
.Height = 20 '高さ
.Width = 100 '幅
.BorderStyle = fmBorderStyleSingle '枠線
.ForeColor = RGB(0, 0, 0) '文字色
.Font.Name = "メイリオ" 'テキストのスタイル
.TextAlign = 2 'テキストの位置
.FontSize = 10 'テキストのサイズ
.IMEMode = fmIMEModeHiragana 'IMEをひらがなに指定する
.TabIndex = i 'タブキーの移動の順番を指定する
End If
i = i + 1
End With
Next
End With
End Sub
設置済みテキストボックスのテキストの取得/入力するサンプルコード
テキストボックスを追加して文字列を入力する
せっかくなので、Sample3で使用したループで5個のテキストボックスを追加するコードを使用して、それぞれのテキストボックスにSample1~5の文字列を入力したいと思います。
Sub Sample5()
Dim MyCtrl As Object
Dim i As Long
With UserForm1
For i = 1 To 5
'テキストボックスの名前に番号を付ける
Set MyCtrl = .Controls.Add("Forms.TextBox.1", "MyText" & i, True)
With MyCtrl
.Top = 24 * i 'Top位置(表示位置を移動する)
.Left = 18 'Left位置
.Height = 20 '高さ
.Width = 100 '幅
.BorderStyle = fmBorderStyleSingle '枠線
.ForeColor = RGB(0, 0, 0) '文字色
.Font.Name = "メイリオ" 'テキストのスタイル
.TextAlign = 2 'テキストの位置
.FontSize = 10 'テキストのサイズ
.IMEMode = fmIMEModeHiragana 'IMEをひらがなに指定する
.TabIndex = i 'タブキーの移動の順番を指定する
.Text = "Sample" & i
End With
Next i
.Show vbModeless
End With
End Sub
テキストボックスに入力されている文字列を取得する
Sub Sample6()
Dim MyCtrl As Object
Dim i As Long
Dim GetCtrl As Object
Dim MyStr As String
With UserForm1
For i = 1 To 5
'テキストボックスの名前に番号を付ける
Set MyCtrl = .Controls.Add("Forms.TextBox.1", "MyText" & i, True)
With MyCtrl
.Top = 24 * i 'Top位置(表示位置を移動する)
.Left = 18 'Left位置
.Height = 20 '高さ
.Width = 100 '幅
.BorderStyle = fmBorderStyleSingle '枠線
.ForeColor = RGB(0, 0, 0) '文字色
.Font.Name = "メイリオ" 'テキストのスタイル
.TextAlign = 2 'テキストの位置
.FontSize = 10 'テキストのサイズ
.IMEMode = fmIMEModeHiragana 'IMEをひらがなに指定する
.TabIndex = i 'タブキーの移動の順番を指定する
.Text = "Sample" & i
End With
Next i
.Show vbModeless
'テキストボックスを取得して入力されているテキストを取得する
i = 1
For Each GetCtrl In .Controls
With GetCtrl
If InStr(.Name, "MyText") <> 0 Then
MyStr = MyStr & vbCrLf & .Text
End If
End With
Next
MsgBox MyStr
End With
End Sub
